Added basic examples

Author: wizard97

examples/Ex_01_SayHello/Ex_01_SayHello.ino

@@ -0,0 +1,44 @@
+/*
+* Example 01: Ex_01_SayHello.ino
+* By: D. Aaron Wisner
+*
+* In this example we are creating a "SayHelloProcess" Class that prints "Hello from Process: 'id'" at a constant period
+*/
+
+#include <ProcessScheduler.h>
+
+// Create my custom process SayHelloProcess
+class SayHelloProcess : public Process
+{
+public:
+    // Call the Process constructor
+    SayHelloProcess(Scheduler &manager, ProcPriority pr, unsigned int period, int iterations)
+        :  Process(manager, pr, period, iterations) {}
+
+protected:
+    // Create our service routine
+    virtual void service()
+    {
+        Serial.print("Hello from Process: ");
+        Serial.println(getID());
+    }
+};
+
+Scheduler sched; // Create a global Scheduler object
+
+// Create our high priority process that will get serviced as often as possible and run forever
+SayHelloProcess myProc(sched, HIGH_PRIORITY, SERVICE_CONSTANTLY, RUNTIME_FOREVER);
+
+void setup()
+{
+    Serial.begin(9600);
+    // Add our process to the scheduler
+    myProc.add();
+    //enable it
+    myProc.enable();
+}
+
+void loop()
+{
+    sched.run();
+}

examples/Ex_02_MultiBlink/Ex_02_MultiBlink.ino

@@ -0,0 +1,73 @@
+/*
+* Example 02: Ex_02_MultiBlink.ino
+* By: D. Aaron Wisner
+*
+* In this example we are creating a "BlinkProcess" Class that will toggle a pin at a constant period
+* We create 3 BlinkProcess objects that will blink at a diff. period and add them to the scheduler:
+* - blink250 (pin 13)
+* - blink500 (pin 12)
+* - blink1000 (pin 11)
+* Connect an LED to each of these pins and watch them blink
+*/
+
+#include <ProcessScheduler.h>
+
+// Create my custom Blink Process
+class BlinkProcess : public Process
+{
+public:
+    // Call the Process constructor
+    BlinkProcess(Scheduler &manager, ProcPriority pr, unsigned int period, int pin)
+        :  Process(manager, pr, period)
+        {
+          _pinState = LOW; // Set the default state
+          _pin = pin; // Store the pin number
+        }
+
+protected:
+    virtual void setup()
+    {
+      pinMode(_pin, OUTPUT);
+      _pinState = LOW;
+      digitalWrite(_pin, _pinState);
+    }
+
+     // Undo setup()
+    virtual void cleanup()
+    {
+      pinMode(_pin, INPUT);
+      _pinState = LOW;
+    }
+
+    // Create our service routine
+    virtual void service()
+    {
+      // If pin is on turn it off, otherwise turn it on
+      _pinState = !_pinState;
+      digitalWrite(_pin, _pinState);
+    }
+
+private:
+    bool _pinState; //the Current state of the pin
+    int _pin; // The pin the LED is on
+};
+
+Scheduler sched; // Create a global Scheduler object
+
+// Create our blink processes
+BlinkProcess blink250(sched, HIGH_PRIORITY, 250, 13); // Blink 13 every 250 ms
+BlinkProcess blink500(sched, HIGH_PRIORITY, 500, 12); // Blink 12 every 500 ms
+BlinkProcess blink1000(sched, HIGH_PRIORITY, 1000, 11); // Blink 11 every 1000 ms
+
+void setup()
+{
+  // Add and enable our blink processes
+  blink250.add(true); // Same as calling blink250.add() and blink250.enable();
+  blink500.add(true);
+  blink1000.add(true);
+}
+
+void loop()
+{
+    sched.run();
+}