RED4ext/CMakeLists.txt at master · wopss/RED4ext · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
cmake_minimum_required(VERSION 3.26)

# ------------------------------------------------------------------------------
# Project variables
# ------------------------------------------------------------------------------
set(RED4EXT_CMAKE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
set(RED4EXT_CMAKE_DEPS_DIR "${RED4EXT_CMAKE_DIR}/deps")
set(RED4EXT_CMAKE_TEMPLATES_DIR "${RED4EXT_CMAKE_DIR}/templates")

# ------------------------------------------------------------------------------
# Modules
# ------------------------------------------------------------------------------
include("${RED4EXT_CMAKE_DIR}/ConfigureDefaultOutputDirectories.cmake")
include("${RED4EXT_CMAKE_DIR}/ConfigureResourceRc.cmake")
include("${RED4EXT_CMAKE_DIR}/ConfigureVersionFile.cmake")
include("${RED4EXT_CMAKE_DIR}/ConfigureVersionFromGit.cmake")
include("${RED4EXT_CMAKE_DIR}/TargetAppendOutputDirectory.cmake")

# ------------------------------------------------------------------------------
# Versioning
# ------------------------------------------------------------------------------
red4ext_configure_version_from_git()

# ------------------------------------------------------------------------------
# Project definition
# ------------------------------------------------------------------------------
project(
  RED4ext
  VERSION "${RED4EXT_GIT_VERSION_MAJOR}.${RED4EXT_GIT_VERSION_MINOR}.${RED4EXT_GIT_VERSION_PATCH}"
  LANGUAGES CXX
)

# ------------------------------------------------------------------------------
# General configuration
# ------------------------------------------------------------------------------
set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

set(CMAKE_INTERPROCEDURAL_OPTIMIZATION_RELEASE ON)
set(CMAKE_INTERPROCEDURAL_OPTIMIZATION_MINSIZEREL ON)
set(CMAKE_INTERPROCEDURAL_OPTIMIZATION_RELWITHDEBINFO ON)
set(CMAKE_MSVC_DEBUG_INFORMATION_FORMAT "ProgramDatabase")

red4ext_configure_default_output_directories()

# ------------------------------------------------------------------------------
# Options
# ------------------------------------------------------------------------------
option(RED4EXT_GIT_METADATA "Append Git metadata to 'RED4EXT_GIT_VERSION' CMake variable." ON)

option(RED4EXT_EXTRA_WARNINGS "Enable extra warnings." ON)
option(RED4EXT_TREAT_WARNINGS_AS_ERRORS "Treat compiler warnings as errors." OFF)

# ------------------------------------------------------------------------------
# Toolchain settings for all targets
# ------------------------------------------------------------------------------
add_compile_definitions(
  UNICODE
  _UNICODE
  WIN32_LEAN_AND_MEAN

  # Support Windows 7 and above.
  WINVER=0x0601
  _WIN32_WINNT=0x0601
)

add_link_options(
  /DEBUG:FULL

  $<$<CONFIG:Release,MinSizeRel,RelWithDebInfo>:/INCREMENTAL:NO>
)

# ------------------------------------------------------------------------------
# Dependencies
# ------------------------------------------------------------------------------
include(FetchContent)

include("${RED4EXT_CMAKE_DEPS_DIR}/Detours.cmake")
include("${RED4EXT_CMAKE_DEPS_DIR}/Fmt.cmake")
include("${RED4EXT_CMAKE_DEPS_DIR}/RED4extSdk.cmake")
include("${RED4EXT_CMAKE_DEPS_DIR}/Redscript.cmake")
include("${RED4EXT_CMAKE_DEPS_DIR}/Simdjson.cmake")
include("${RED4EXT_CMAKE_DEPS_DIR}/Spdlog.cmake")
include("${RED4EXT_CMAKE_DEPS_DIR}/Toml11.cmake")
include("${RED4EXT_CMAKE_DEPS_DIR}/Wil.cmake")

# ------------------------------------------------------------------------------
# Toolchain settings for this project only
# ------------------------------------------------------------------------------
add_compile_definitions(
  NOMINMAX
)

add_compile_options(
  /GS
  /sdl

  /permissive-
  /Zc:__cplusplus
  /Zc:__STDC__
  /Zc:enumTypes
  /Zc:inline
  /Zc:preprocessor
  /Zc:templateScope

  $<$<CONFIG:Release,MinSizeRel,RelWithDebInfo>:/Gy>
  $<$<CONFIG:Release,MinSizeRel,RelWithDebInfo>:/Oi>

  # Disable some warnings that are not relevant to us.
  /external:I${FETCHCONTENT_BASE_DIR}
  /external:W0
)

if(RED4EXT_EXTRA_WARNINGS)
  add_compile_options(/W4)
endif()

if(RED4EXT_TREAT_WARNINGS_AS_ERRORS)
  add_compile_options(/WX)
endif()

# ------------------------------------------------------------------------------
# Main projects
# ------------------------------------------------------------------------------
add_subdirectory(src)

# ------------------------------------------------------------------------------
# Install
# ------------------------------------------------------------------------------
if(NOT CMAKE_SKIP_INSTALL_RULES)
  set(RED4EXT_INSTALL_X64_DIR bin/x64)
  set(RED4EXT_INSTALL_BIN_DIR red4ext)

  install(
    TARGETS RED4ext.Loader
    RUNTIME DESTINATION "${RED4EXT_INSTALL_X64_DIR}"
  )

  install(
    FILES $<TARGET_PDB_FILE:RED4ext.Loader>
    DESTINATION "${RED4EXT_INSTALL_X64_DIR}"
  )

  install(
    TARGETS RED4ext.Dll
    RUNTIME DESTINATION "${RED4EXT_INSTALL_BIN_DIR}"
  )

  install(
    FILES $<TARGET_PDB_FILE:RED4ext.Dll>
    DESTINATION "${RED4EXT_INSTALL_BIN_DIR}"
  )

  install(
    FILES "${PROJECT_SOURCE_DIR}/LICENSE.md"
    DESTINATION "${RED4EXT_INSTALL_BIN_DIR}"
    RENAME LICENSE.txt
  )

  install(
    FILES "${PROJECT_SOURCE_DIR}/THIRD_PARTY_LICENSES.md"
    DESTINATION "${RED4EXT_INSTALL_BIN_DIR}"
    RENAME THIRD_PARTY_LICENSES.txt
  )
endif()