feat: use facts to auto-retrieve node versions if possible

e2e/nodejs_host/BUILD.bazel

@@ -1,3 +1,4 @@
+load("@bazel_features//:features.bzl", "bazel_features")
 load("@rules_shell//shell:sh_test.bzl", "sh_test")
 
 # Dummy test target that imports various targets from the
@@ -23,7 +24,9 @@ load("@rules_shell//shell:sh_test.bzl", "sh_test")
         "node16",
         "node16_nvmrc",
         "node17_custom",
-    ]
+    ] + (
+        ["node26_facts"] if bazel_features.external_deps.has_facts else []
+    )
 ]
 
 [
@@ -66,5 +69,10 @@ load("@rules_shell//shell:sh_test.bzl", "sh_test")
         ("node16_nvmrc", "npx"),
         ("node17_custom", "npm"),
         ("node17_custom", "npx"),
-    ]
+    ] + (
+        [
+            ("node26_facts", "npm"),
+            ("node26_facts", "npx"),
+        ] if bazel_features.external_deps.has_facts else []
+    )
 ]

e2e/nodejs_host/MODULE.bazel

@@ -6,6 +6,7 @@ local_path_override(
 
 bazel_dep(name = "bazel_lib", version = "3.0.0-beta.1")
 bazel_dep(name = "bazel_skylib", version = "1.7.1")
+bazel_dep(name = "bazel_features", version = "1.49.0")
 bazel_dep(name = "rules_shell", version = "0.6.1")
 
 node = use_extension("@rules_nodejs//nodejs:extensions.bzl", "node")
@@ -35,6 +36,10 @@ node.toolchain(
     node_urls = ["https://nodejs.org/dist/v17.0.1/{filename}"],
     node_version = "17.0.1.custom",
 )
+node.toolchain(
+    name = "node26_facts",
+    node_version = "26.3.0",
+)
 
 # FIXME(6.0): a repo rule with name=foo should create a repo named @foo, not @foo_toolchains
 use_repo(
@@ -60,6 +65,13 @@ use_repo(
     "node17_custom_linux_arm64",
     "node17_custom_toolchains",
     "node17_custom_windows_amd64",
+    "node26_facts",
+    "node26_facts_darwin_amd64",
+    "node26_facts_darwin_arm64",
+    "node26_facts_linux_amd64",
+    "node26_facts_linux_arm64",
+    "node26_facts_toolchains",
+    "node26_facts_windows_amd64",
     "nodejs",
     "nodejs_darwin_amd64",
     "nodejs_darwin_arm64",

nodejs/BUILD.bazel

@@ -9,7 +9,13 @@ package(default_visibility = ["//visibility:public"])
 bzl_library(
     name = "extensions",
     srcs = ["extensions.bzl"],
-    deps = [":repositories"],
+    deps = [
+        ":repositories",
+        "//nodejs/private:fetch_node_repositories",
+        "//nodejs/private:node_versions",
+        "//nodejs/private:version_from_attr",
+        "@bazel_features//:features",
+    ],
 )
 
 bzl_library(
@@ -29,6 +35,7 @@ bzl_library(
         "//nodejs/private:nodejs_repo_host_os_alias",
         "//nodejs/private:nodejs_toolchains_repo",
         "//nodejs/private:os_name",
+        "//nodejs/private:version_from_attr",
     ],
 )
 

nodejs/extensions.bzl

@@ -9,6 +9,10 @@ use_repo(node, "nodejs_toolchains")
 ```
 """
 
+load("@bazel_features//:features.bzl", "bazel_features")
+load("//nodejs/private:fetch_node_repositories.bzl", "fetch_node_repositories")
+load("//nodejs/private:node_versions.bzl", "NODE_VERSIONS")
+load("//nodejs/private:version_from_attr.bzl", "version_from_attr")
 load(
     ":repositories.bzl",
     "DEFAULT_NODE_REPOSITORY",
@@ -52,17 +56,45 @@ def _toolchain_extension(module_ctx):
             else:
                 registrations[toolchain.name] = toolchain
 
+    supports_facts = hasattr(module_ctx, "facts")
+    new_repository_facts = {}
+
     for k, v in registrations.items():
+        node_version = version_from_attr(module_ctx, v)
+        node_repositories = v.node_repositories or NODE_VERSIONS.get(node_version, {})
+
+        if supports_facts and not node_repositories:
+            node_repositories = (
+                new_repository_facts.get(node_version) or
+                module_ctx.facts.get(node_version) or
+                # TODO: Add support for node_urls?
+                fetch_node_repositories(module_ctx, node_version)
+            )
+            new_repository_facts[node_version] = node_repositories
+
         nodejs_register_toolchains(
             name = k,
-            node_version = v.node_version,
-            node_version_from_nvmrc = v.node_version_from_nvmrc,
+            node_version = node_version,
             node_urls = v.node_urls,
-            node_repositories = v.node_repositories,
+            node_repositories = node_repositories,
             include_headers = v.include_headers,
             register = False,
         )
 
+    if not hasattr(module_ctx, "extension_metadata"):
+        return  # buildifier: disable=return-value (allow no value)
+
+    if not bazel_features.external_deps.extension_metadata_has_reproducible:
+        return module_ctx.extension_metadata()
+
+    if not supports_facts:
+        return module_ctx.extension_metadata(reproducible = True)
+
+    return module_ctx.extension_metadata(
+        reproducible = True,
+        facts = new_repository_facts,
+    )
+
 _ATTRS = {
     "name": attr.string(
         doc = "Base name for generated repositories",

nodejs/private/BUILD.bazel

@@ -41,3 +41,13 @@ bzl_library(
     srcs = ["user_build_settings.bzl"],
     deps = ["//nodejs/private/providers:user_build_settings"],
 )
+
+bzl_library(
+    name = "version_from_attr",
+    srcs = ["version_from_attr.bzl"],
+)
+
+bzl_library(
+    name = "fetch_node_repositories",
+    srcs = ["fetch_node_repositories.bzl"],
+)

nodejs/private/fetch_node_repositories.bzl

@@ -0,0 +1,58 @@
+"""Implementation of node SHASUM fetching for facts."""
+
+_REPOSITORY_TYPES = {
+    "darwin-arm64.tar.gz": "darwin_arm64",
+    "darwin-x64.tar.gz": "darwin_amd64",
+    "linux-x64.tar.xz": "linux_amd64",
+    "linux-arm64.tar.xz": "linux_arm64",
+    "linux-s390x.tar.xz": "linux_s390x",
+    "win-x64.zip": "windows_amd64",
+    "win-arm64.zip": "windows_arm64",
+    "linux-ppc64le.tar.xz": "linux_ppc64le",
+}
+
+def fetch_node_repositories(module_ctx, version):
+    """Fetches node repositories for the given node version.
+
+    Port of scripts/update-nodejs-versions.js
+
+    Args:
+      module_ctx: Module context
+      version: The node version to fetch repositories for.
+
+    Returns:
+      A dictionary in the shape of node_repositories.
+    """
+
+    shasums_filename = "{version}-SHASUMS256.txt".format(version = version)
+    url = "https://nodejs.org/dist/v{version}/SHASUMS256.txt".format(version = version)
+
+    result = module_ctx.download(url = url, output = shasums_filename)
+    if not result.success:
+        fail("Failed to fetch node shasums:", url, result, sep = "\n")
+
+    shasums = module_ctx.read(shasums_filename)
+
+    result = {}
+
+    for line in shasums.splitlines():
+        line = line.strip()
+        if not line:
+            continue
+
+        parts = line.split("  ")
+        if len(parts) != 2:
+            fail("{url} contains unexpected line:\n{line}".format(
+                url = url,
+                line = line,
+            ))
+
+        sha, filename = parts
+        type = _REPOSITORY_TYPES.get(filename.removeprefix("node-v%s-" % version))
+        if not type:
+            continue
+
+        strip_prefix = filename.removesuffix(".tar.gz").removesuffix(".tar.xz").removesuffix(".zip")
+        result[version + "-" + type] = (filename, strip_prefix, sha)
+
+    return result

nodejs/private/version_from_attr.bzl

@@ -0,0 +1,28 @@
+"""Helper to get node version from user config."""
+
+def _verify_version_is_valid(version):
+    major, minor, patch = (version.split(".") + [None, None, None])[:3]
+    if not major.isdigit() or not minor.isdigit() or not patch.isdigit():
+        fail("Invalid node version: %s" % version)
+
+def version_from_attr(ctx, attr):
+    """Extract the node version from attr.
+
+    Verifies if the extracted version is valid.
+
+    Args:
+      ctx: repository or module context
+      attr: A struct with fields node_version and node_version_from_nvmrc
+
+    Returns:
+      The node version.
+    """
+
+    node_version = attr.node_version
+
+    if attr.node_version_from_nvmrc:
+        node_version = str(ctx.read(attr.node_version_from_nvmrc)).strip()
+
+    _verify_version_is_valid(node_version)
+
+    return node_version

nodejs/repositories.bzl

@@ -3,6 +3,7 @@
 load("//nodejs/private:node_versions.bzl", "NODE_VERSIONS")
 load("//nodejs/private:nodejs_repo_host_os_alias.bzl", "nodejs_repo_host_os_alias")
 load("//nodejs/private:nodejs_toolchains_repo.bzl", "PLATFORMS", "nodejs_toolchains_repo")
+load("//nodejs/private:version_from_attr.bzl", "version_from_attr")
 
 # Default base name for node toolchain repositories
 # created by the module extension
@@ -66,12 +67,7 @@ def _download_node(repository_ctx):
     # @nodejs_PLATFORM where PLATFORM is one of BUILT_IN_NODE_PLATFORMS
     host_os = repository_ctx.attr.platform or repository_ctx.name.split("nodejs_", 1)[1]
 
-    node_version = repository_ctx.attr.node_version
-
-    if repository_ctx.attr.node_version_from_nvmrc:
-        node_version = str(repository_ctx.read(repository_ctx.attr.node_version_from_nvmrc)).strip()
-
-    _verify_version_is_valid(node_version)
+    node_version = version_from_attr(repository_ctx, repository_ctx.attr)
 
     node_repositories = repository_ctx.attr.node_repositories
 
@@ -302,11 +298,6 @@ def _strip_bin(path):
 
     return path[len("bin/"):]
 
-def _verify_version_is_valid(version):
-    major, minor, patch = (version.split(".") + [None, None, None])[:3]
-    if not major.isdigit() or not minor.isdigit() or not patch.isdigit():
-        fail("Invalid node version: %s" % version)
-
 def _nodejs_repositories_impl(repository_ctx):
     reproducible = _download_node(repository_ctx)
     _prepare_node(repository_ctx)