feat(tray): Migrate TrayWindow to the new tray user menu

resources.qrc

@@ -1,6 +1,12 @@
 <RCC>
     <qresource prefix="/qml">
         <file>src/gui/UserStatusMessageView.qml</file>
+        <file>src/gui/UserStatusWindow.qml</file>
+        <file>src/gui/WindowAccountHeader.qml</file>
+        <file>src/gui/ActivitiesWindow.qml</file>
+        <file>src/gui/AssistantWindow.qml</file>
+        <file>src/gui/UserStatusWindowStatusRow.qml</file>
+        <file>src/gui/UserStatusWindowPredefinedStatusRow.qml</file>
         <file>src/gui/UserStatusSelectorPage.qml</file>
         <file>src/gui/EmojiPicker.qml</file>
         <file>src/gui/UserStatusSelectorButton.qml</file>
@@ -22,7 +28,6 @@
         <file>src/gui/filedetails/ShareeSearchField.qml</file>
         <file>src/gui/filedetails/ShareView.qml</file>
         <file>src/gui/tray/MainWindow.qml</file>
-        <file>src/gui/tray/TrayAccountPopup.qml</file>
         <file>src/gui/tray/UserLine.qml</file>
         <file>src/gui/tray/HeaderButton.qml</file>
         <file>src/gui/tray/SyncStatus.qml</file>

src/gui/ActivitiesWindow.qml

@@ -0,0 +1,182 @@
+/*
+ * SPDX-FileCopyrightText: 2026 Nextcloud GmbH and Nextcloud contributors
+ * SPDX-License-Identifier: GPL-2.0-or-later
+ */
+
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Layouts
+
+import Style
+import "./tray"
+
+ApplicationWindow {
+    id: root
+
+    property int userIndex: -1
+    property var currentUser: null
+    property var activityModel: null
+    readonly property string headline: qsTr("Activities")
+
+    LayoutMirroring.enabled: Application.layoutDirection === Qt.RightToLeft
+    LayoutMirroring.childrenInherit: true
+
+    title: ""
+    width: Style.activitiesWindowWidth
+    height: Style.activitiesWindowHeight
+    minimumWidth: Style.wizardStandaloneWindowMinimumWidth
+    minimumHeight: Style.wizardStandaloneWindowMinimumHeight
+    flags: Qt.Window
+        | Qt.CustomizeWindowHint
+        | Qt.WindowTitleHint
+        | Qt.WindowSystemMenuHint
+        | Qt.WindowCloseButtonHint
+    color: Style.wizardWindowBackground
+    palette.window: Style.wizardWindowBackground
+    palette.windowText: Style.wizardPrimaryText
+    palette.base: Style.wizardFieldBackground
+    palette.text: Style.wizardPrimaryText
+    palette.button: Style.wizardFieldBackground
+    palette.buttonText: Style.wizardPrimaryText
+    palette.mid: Style.wizardDisabledText
+    palette.placeholderText: Style.wizardPlaceholderText
+
+    background: Rectangle {
+        color: Style.wizardWindowBackground
+    }
+
+    function reloadForCurrentUser() {
+        newActivitiesButtonLoader.active = false
+        syncStatus.model.loadForUser(root.currentUser)
+    }
+
+    Shortcut {
+        sequences: [StandardKey.Cancel]
+        onActivated: root.close()
+    }
+
+    Component.onCompleted: reloadForCurrentUser()
+
+    onVisibleChanged: {
+        if (visible) {
+            reloadForCurrentUser()
+        }
+    }
+
+    ColumnLayout {
+        anchors.fill: parent
+        anchors.leftMargin: Style.wizardWindowMargin
+        anchors.rightMargin: Style.wizardWindowMargin
+        anchors.topMargin: Style.wizardWindowTopMargin
+        anchors.bottomMargin: Style.wizardWindowMargin
+        spacing: Style.wizardSectionSpacing
+
+        WindowAccountHeader {
+            Layout.fillWidth: true
+            title: root.headline
+            user: root.currentUser
+        }
+
+        Rectangle {
+            Layout.fillWidth: true
+            Layout.preferredHeight: Style.normalBorderWidth
+            color: Style.wizardRowBorder
+        }
+
+        SyncStatus {
+            id: syncStatus
+
+            Layout.fillWidth: true
+            accentColor: Style.accentColor
+            user: root.currentUser
+            activityListModel: root.activityModel
+        }
+
+        Rectangle {
+            Layout.fillWidth: true
+            Layout.preferredHeight: Style.normalBorderWidth
+            color: Style.wizardRowBorder
+        }
+
+        Item {
+            Layout.fillWidth: true
+            Layout.fillHeight: true
+
+            ActivityList {
+                id: activityList
+
+                anchors.fill: parent
+                activeFocusOnTab: true
+                model: root.activityModel
+                onOpenFile: Qt.openUrlExternally(filePath)
+                onActivityItemClicked: {
+                    if (root.activityModel) {
+                        root.activityModel.slotTriggerDefaultAction(index)
+                    }
+                }
+
+                Connections {
+                    target: root.activityModel
+
+                    function onInteractiveActivityReceived() {
+                        if (!activityList.atYBeginning) {
+                            newActivitiesButtonLoader.active = true
+                        }
+                    }
+                }
+            }
+
+            Loader {
+                id: newActivitiesButtonLoader
+
+                anchors.top: activityList.top
+                anchors.topMargin: Style.smallSpacing
+                anchors.horizontalCenter: activityList.horizontalCenter
+                width: Style.newActivitiesButtonWidth
+                height: Style.newActivitiesButtonHeight
+                z: 1
+                active: false
+
+                sourceComponent: Button {
+                    id: newActivitiesButton
+
+                    anchors.fill: parent
+                    hoverEnabled: true
+                    padding: Style.smallSpacing
+                    text: qsTr("New activities")
+                    icon.source: "image://svgimage-custom-color/expand-less-black.svg/" + Style.currentUserHeaderTextColor
+                    icon.width: Style.activityListButtonIconSize
+                    icon.height: Style.activityListButtonIconSize
+                    Accessible.role: Accessible.Button
+                    Accessible.name: text
+                    Accessible.onPressAction: newActivitiesButton.clicked()
+                    onClicked: {
+                        activityList.scrollToTop()
+                        newActivitiesButtonLoader.active = false
+                    }
+
+                    Timer {
+                        id: newActivitiesButtonDisappearTimer
+
+                        interval: Style.newActivityButtonDisappearTimeout
+                        running: newActivitiesButtonLoader.active && !newActivitiesButton.hovered
+                        repeat: false
+                        onTriggered: fadeoutActivitiesButtonDisappear.running = true
+                    }
+
+                    OpacityAnimator {
+                        id: fadeoutActivitiesButtonDisappear
+
+                        target: newActivitiesButton
+                        from: 1
+                        to: 0
+                        duration: Style.newActivityButtonDisappearFadeTimeout
+                        loops: 1
+                        running: false
+                        onFinished: newActivitiesButtonLoader.active = false
+                    }
+                }
+            }
+        }
+    }
+}